Pattern Based Exit

Dies ist ein einfacher Pattern-based Exit. Er eignet sich, um Impulsbewegungen zu handeln. Vola Ausbrüche, scharfe Trends, Trades nach Nachrichten.

Die Idee hinter diesem Exit ist folgende: (long, short analog)

Wenn wir heute über dem Hoch von Gestern schließen, dann ist das sehr bullish. Letztendlich sind wir heute zu einem Preis bereit die Position über Nacht z halten, zu dem wir sie gestern noch nicht einmal haben wollten. (Close>Hoch(gestern)).

Sollte nun der Markt drehen und das Tief des heutigen Tages morgen unterschritten werden, dann schließen wir die Position an diesem Tief.

Wenn Close(heute)>Hoch(gestern) dann Stop(morgen) bei Tief(heute).

Tradesignal Equilla Code

Wenn Euphorie in Panik umschlägt, dann soll mein Handelssystem nicht länger Long sein…

if close>high[1] then sell next bar at low stop;
if close<low[1] then cover next bar at high stop;

 Swin Punkte als Stop verwenden

Swing Punkte sind  lokale Hochs oder Tiefs Sie eignen sich vorzüglich um bei trendfolgenden Systemen einen Chart basierten Stop zu setzten.

Swing Point Trailing Stop

Ein Swing Tief ist hierbei ein Tief, das rechts und links von einem höheren Tief umgeben ist.
Und entsprechend der Dow Theorie ist der Aufwärtstrend vorbei, sobald das vorhergehende Tief unterschritten wird. Das macht diese einfach zu definierenden Punkte zu einem idealen Ort für den Stop.

Aufgrund der sehr einfachen 3-bar Definition eines solchen Punktes, ist es vorteilhaft, den Stop mit längerfristigen Daten zu verwenden. Diese beinhalten weniger Rauschen, und das hilft dem einfachen Code.

Beispiel Handelssystem Swing Stop:

Hier ein Beispiel für eine Handelsstrategie bestehend aus dem sample Entry aus der Trader Toolbox und dem Swing Stop am Euro /weekly data:

euro swing langfrist

Tradesignal Handelssystem Code Swing Stop:

Meta: Synopsis("Sets stop to chart based reversal points (3 bar swing)");
Inputs: IgnoreInsideCandles(false);
Variables:oo,cc, hh(invalid),ll,hh1,hh2,ll1,ll2, sh, sl;

if ignoreinsidecandles=false then begin
  if l>l[1] and l[1]<l[2] then sl=l[1];
  if h<h[1] and h[1]>h[2] then sh=h[1];
end;


if ignoreinsidecandles then begin
  if hh=invalid then begin
    hh=h;
    cc=c;
    ll=l;
    oo=o;
  end;
  
  if h crosses above hh or l crosses below ll then begin
    hh2=hh1;
    ll2=ll1;
    hh1=hh;
    ll1=ll;
    hh=h;
    cc=c;
    ll=l;
    oo=o;
    
    if ll>ll1 and ll1<ll2 then sl=ll1;
    if hh<hh1 and hh1>hh2 then sh=hh1;
  end;
end;


cover next bar at sh stop;
sell next bar at sl stop;

drawsymbol(getactiveorderprice(1));
drawsymbol(getactiveorderprice(2));

Wenn man schon spekuliert, dann sollte die Spekulation auch nach einer gewissen Zeit im Plus sein. Ansonsten hat man vermutlich für den Einstieg den falschen Zeitpunkt gewählt und es ist schlauer die Position zu schließen und sich was besseres zu überlegen.

Unterschätzen Sie nie das “allgemeine Marktrisiko”. Gegen gewöhnliche Kursschwankungen kann man sich mit Hilfe eines schlau gewählten Stops absichern, aber denken Sie an unvorhersehbare Gaps, Revolutionen oder politische Einflussnahmen, es ist immer besser nicht investiert zu sein, wenn es keinen guten Grund gibt sich dem Risiko der Spekulation auszusetzen.

Solch ein Zeit Stop lässt sich denkbar einfach programmieren. Speichern Sie die Zeilen als Strategie oder fügen Sie sie Ihrem Code hinzu.

Inputs: TimeToRun(5);

if barssinceentry>=TimeToRun then setstoploss(0);

Damit wird die Position nach 5 (oder mehr) bars geschlossen, falls sie im Verlust ist oder daran denken sollte nochmal in die Verlustzone zu kommen.

Dieser einfache Code sichert die Gewinne ihres Handelssystems.

Über den Input “visuals” können sie entscheiden, ob der Code den Stop am Chart anzeigen soll oder nicht.

// % trailing stop.
Meta: Synopsis("Trailing Stop in %");
Inputs: PercentTrailing(10.0), visuals(true), StopOnEntryBar(false);
Variables: hh, ll;

If barssinceentry>=0 then begin
  hh=highest(high,maxlist(1,barssinceentry+1));
  ll=lowest(low,maxlist(1,barssinceentry+1));
  
  if marketposition=1 then sell next bar at hh-percentTrailing*hh/100 stop;
  if marketposition=-1 then cover next bar at ll+percentTrailing*ll/100 stop;
end;

setstopcontract;
If StopOnEntryBar then setstoploss(close/100*percenttrailing*lotsize); // close used, as entryprice is not available at first bar

if visuals=true then drawsymbol(getactiveorderprice(1));